Haiku Gallery

\ {{ Add a wave by DarkstarAG
: x x ;
( : y x .5 - t cos y .5 * cos 2 / 1 + - * ; )
: y x t 3 / 1.57 4 / mod - 30 * 1 cos * cos 40 / y + ;
\ }} Add a wave

( Visualization of f[x,y] )
( Multiple viewport )
( Animation )

: n 1 + 2 / ;
: ^2 dup * ;
: ^3 dup dup * * ;
: c+ ( a b c d e f - a+d b+e c+f ) rot >r z+ rot r> + -rot ;
: c*k ( a b c k - ka kb kc ) 0 over >r z* rot r> * -rot ;
: clip 0 max 1 min ;

: xy x y -.5 -.5 z+ ;
: item ( x - d x' ) dup 256 mod 256 / swap 256 / floor ;

: color ( x - r g b ) 16777216 * floor item item item drop ;
: pack-color ( r g b - .f ) 256 * + 256 * + 256 * 16777618 / ;

: fix8 ( x - x' ) 256 * floor 256 / ;

: banana ( x y - ) over ^2 - ^2 100 * 1 swap - ^2 + ;

: rainbow ( .f - r g b )
dup 3 * 1 + sin swap
dup 3 * 0 + sin swap
dup 3 * 5 + sin swap drop ;

: cells ( x y - f ) sin swap sin * 1 + 2 / ;

: astroida ( x y R - f ) 0.6667 ** swap .6667 ** - swap .6667 ** - negate ;

: heart ( x y - f ) 2dup ^2 swap ^3 + 1 - ^3 -rot ^3 swap ^2 * - ;

( astroida )
xy .25 -.25 z+ 25 0 z* 1 astroida t 2 * sin .4 * + clip rainbow x .5 < y .5 > * c*k

( cells )
xy 25 0 z* cells rainbow
x .5 < y .5 < * c*k
c+

( banana )
xy -.25 -.1 z+ 4 0 z* banana t sin + clip rainbow
x .5 > y .5 > * c*k
c+

( cardioida heart ? )
xy -.22 .25 z+ 10 0 z* heart 3 ** abs t sin + rainbow
x .5 > y .5 < * c*k
c+

Surfaces MultiViews waves DarkstarAG
'15 Sep 10

Alien Biomorph 2 waves DarkstarAG
'15 Sep 10

Breathing Spiral waves DarkstarAG
'15 Sep 10

Vietnam Gold Star waves DarkstarAG
'15 Sep 10

moon festival waves DarkstarAG
'15 Sep 10

Cube waves DarkstarAG
'15 Sep 10

Haiku Gallery

Next